// Author: Robert Lie (Mobilefish.com)
// More information, see: https://www.mobilefish.com/developer/flash/flash_quickguide_actionscript_3_examples.html

var url:String = "https://www.mobilefish.com/php/tests/actionscript/actionscript_contact.php";
var form:MovieClip = contact_mc;

function loadHandler(e:MouseEvent):void {
	// first check the fields
	var name_txt:String = form.name_txt.text;
	var subject_txt:String = form.subject_txt.text;
	var message_txt:String = form.message_txt.text;
	var allFields:Boolean = true;

	// check name
	if(name_txt.length == 0) {
		allFields = false;
	}

	// check subject
	if(subject_txt.length == 0){
		allFields = false;
	}

	// check message
	if(message_txt.length == 0){
		allFields = false;
	}

	if(!allFields) {
		form.status_txt.htmlText = "<font color='#ff0000'>All required fields not filled in!</font>";
		return;
	}

	var variables:URLVariables = new URLVariables();
	variables.name = name_txt;
	variables.subject = subject_txt;
	variables.message = message_txt;
	var urlRequest:URLRequest = new URLRequest(url);
	urlRequest.method = URLRequestMethod.POST;
	urlRequest.data = variables;
	var urlLoader:URLLoader = new URLLoader();
	urlLoader.addEventListener(Event.COMPLETE, callServerHandler);
	urlLoader.load(urlRequest);
}

function callServerHandler(e:Event):void {
	var urlLoader:URLLoader = URLLoader(e.target);
	var variables:URLVariables = new URLVariables(urlLoader.data);
	if(variables.resultCode == "OK") {
		// message sent
		form.status_txt.htmlText = "<font color='#009933'>Email sent, thank you.</font>";
	} else if(variables.resultCode == "ERROR") {
		// message not sent
		form.status_txt.htmlText = "<font color='#ff0000'>Email not sent, please try again.</font>";
	} else {
		// message not sent, unknown error
		form.status_txt.htmlText = "<font color='#ff0000'>Unknown error.</font>";
	}
}

form.send_btn.addEventListener(MouseEvent.CLICK, loadHandler);